#version 400 core

#define NR_POINT_LIGHTS 10

layout (location = 0) out vec4 accum;
layout (location = 1) out float reveal;


layout (std140) uniform Lights {
    //                                        this is how many      because we have to align
    //                                        bytes it SHOULD       in multiples of 16, this
    //                                        take                  it where it ACTUALLY is
    //
    //refer: https://learnopengl.com/Advanced-OpenGL/Advanced-GLSL
    //
    //                                        base alignment        aligned offset
    //direct light
    vec3 dLDirection;                      // 16                    0
    vec3 dLAmbient;                        // 16                    16
    vec3 dLDiffuse;                        // 16                    32
    vec3 dLSpecular;                       // 16                    48

    //point light
    vec3 pLposition[NR_POINT_LIGHTS];      // 16*10                 64
    float pLconstant[NR_POINT_LIGHTS];     // 16*10                 224
    float pLlinear[NR_POINT_LIGHTS];       // 16*10                 384
    float pLquadratic[NR_POINT_LIGHTS];    // 16*10                 544
    vec3 pLambient[NR_POINT_LIGHTS];       // 16*10                 704
    vec3 pLdiffuse[NR_POINT_LIGHTS];       // 16*10                 864
    vec3 pLspecular[NR_POINT_LIGHTS];      // 16*10                 1024

    //for a total size of   1184

};

struct Material {
    sampler2D diffuse;
    sampler2D specular;
    float shininess;
}; 


//inputs
in vec3 FragPos;
in vec3 Normal;
in vec2 TexCoord;
in vec4 FragPosLightSpace;


//view position
uniform vec3 viewPos;

//material
uniform Material material;



//light depth map
uniform sampler2D shadowMap;


//function prototypes
float calcLightIntensityTotal(vec3 normal);
float ShadowCalculation(vec4 fragPosLightSpace, vec3 lightDir, vec3 normal);
float linearizeDepth(float d,float zNear,float zFar);
float weightCalcOrigin(float finalAlpha, float zLoc, float linearizedLoc);
float weightCalcFlat(float finalAlpha, float zLoc, float linearizedLoc);
float weightCalcNew(float finalAlpha, float zLoc, float linearizedLoc);


void main(){

    vec3 norm = normalize(Normal);
    vec3 viewDir = normalize(viewPos - FragPos);
    
    //grab light intensity
    float lightIntensity = calcLightIntensityTotal(norm);

    //get color of base texture
    vec4 textureColor = texture(material.diffuse, TexCoord);
    vec3 textureRGB = textureColor.rgb;

    //shadow
    float shadow = ShadowCalculation(FragPosLightSpace, normalize(-dLDirection), norm);
    vec3 shadowModifiedColor = textureRGB * lightIntensity * max(shadow, 0.4);

    //calculate final color
    vec4 finalColor = vec4(shadowModifiedColor,textureColor.a);

    //calculate weight function
    float weight = clamp(pow(min(1.0, finalColor.a * 10.0) + 0.01, 3.0) * 1e8 * 
                        pow(1.0 - gl_FragCoord.z * 0.9, 3.0), 1e-2, 3e3);

    //emit colors
    accum = vec4(finalColor.rgb * finalColor.a, finalColor.a) * weight;
    reveal = finalColor.a;
}

//a weight calculation
float weightCalcOrigin(float finalAlpha, float zLoc, float linearizedLoc){
    float weight = clamp(pow(min(1.0, finalAlpha * 10.0) + 0.01, 3.0) * 1e8 * 
                         pow(1.0 - zLoc * 0.9, 3.0), 1e-2, 3e3);
    return weight;
}

//a weight calculation
float weightCalcFlat(float finalAlpha, float zLoc, float linearizedLoc){
    return 0.1f;
}

//a weight calculation
float weightCalcNew(float finalAlpha, float zLoc, float linearizedLoc){
    float alphaComponent = pow(min(1.0, finalAlpha * 10.0) + 0.01, 3.0);
    float zComponent = pow(1.0 - zLoc * 0.9, 3.0);
    
    float weightRaw = alphaComponent * 1e8 * zComponent;
    float weight = clamp(weightRaw, 1e-2, 3e3);
    return weight;
}

//Linearizes the depth
float linearizeDepth(float d,float zNear,float zFar){
    return zNear * zFar / (zFar + d * (zNear - zFar));
}



float calcLightIntensityAmbient(){
    //calculate average of ambient light
    float avg = (dLAmbient.x + dLAmbient.y + dLAmbient.z)/3.0;
    return avg;
}

//
float calcLightIntensityDir(vec3 normal){
    vec3 lightDir = normalize(-dLDirection);
    // diffuse shading
    float diff = max(dot(normal, lightDir), 0.0);
    
    return diff;
}

//
float calcLightIntensityTotal(vec3 normal){
    //ambient intensity
    float ambientLightIntensity = calcLightIntensityAmbient();

    //get direct intensity
    float directLightIntensity = calcLightIntensityDir(normal);

    //sum
    float total = ambientLightIntensity + directLightIntensity;
    return total;
}

//
vec3 getTotalLightColor(vec3 normal){
    //get the direct light color adjusted for intensity
    vec3 diffuseLightColor = dLDiffuse * calcLightIntensityDir(normal);

    //sum light colors
    vec3 totalLightColor = diffuseLightColor;
    return totalLightColor;
}

vec3 CalcPointLight(int i, vec3 normal, vec3 fragPos, vec3 viewDir){
    vec3 lightDir = normalize(pLposition[i] - fragPos);
    // diffuse shading
    float diff = max(dot(normal, lightDir), 0.0);
    // specular shading
    // vec3 reflectDir = reflect(-lightDir, normal);
    // float spec = pow(max(dot(viewDir, reflectDir), 0.0), material.shininess);
    // attenuation
    float distance = length(pLposition[i] - fragPos);
    float attenuation = 1.0 / (pLconstant[i] + pLlinear[i] * distance + pLquadratic[i] * (distance * distance));    
    // combine results
    vec3 ambient = pLambient[i];// * vec4(texture(material.diffuse, TexCoord)).xyz;
    vec3 diffuse = pLdiffuse[i] * diff;// * vec4(texture(material.diffuse, TexCoord)).xyz;
    // vec3 specular = pLspecular[i] * spec;// * vec4(texture(material.specular, TexCoord)).xyz;
    ambient *= attenuation;
    diffuse *= attenuation;
    // specular *= attenuation;
    vec3 specular = vec3(0,0,0);

    vec3 finalValue = (ambient + diffuse + specular);
    finalValue = vec3(max(finalValue.x,0),max(finalValue.y,0),max(finalValue.z,0));

    return finalValue;
}




float ShadowCalculation(vec4 fragPosLightSpace, vec3 lightDir, vec3 normal){

    // perform perspective divide
    vec3 projCoords = fragPosLightSpace.xyz / fragPosLightSpace.w;

    //transform to NDC
    projCoords = projCoords * 0.5 + 0.5;

    //get closest depth from light's POV
    float closestDepth = texture(shadowMap, projCoords.xy).r;

    //get depth of current fragment
    float currentDepth = projCoords.z;
    
    //calculate bias
    float bias = max(0.05 * (1.0 - dot(normal, lightDir)), 0.005);

    //calculate shadow value
    float shadow = currentDepth - bias > closestDepth  ? 1.0 : 0.0;

    if(projCoords.z > 1.0){
        shadow = 0.0;
    }

    //calculate dot product, if it is >0 we know they're parallel-ish therefore should disregard the shadow mapping
    //ie the fragment is already facing away from the light source
    float dotprod = dot(normalize(lightDir),normalize(normal));

    if(dotprod > 0.0){
        shadow = 0.0;
    }

    // shadow = currentDepth;

    return shadow;
}