Renderer/assets/Shaders/entities/terrain2/terrain2.fs

#version 450 core

//texture defines
#define ATLAS_ELEMENT_DIM 256.0
#define ATLAS_DIM 8192.0
#define ATLAS_EL_PER_ROW 32
#define ATLAS_NORMALIZED_ELEMENT_WIDTH 0.031 //within the single texture within the atlas, we use this so we never go over the end of the texture
#define ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL 0.03125 //used to properly shift from texture to texture in the atlas


/**
Bind points for different SSBOs
*/
#define CLUSTER_SSBO_BIND_POINT 1
#define POINT_LIGHT_SSBO_BIND_POINT 2
#define DIRECT_LIGHT_SSBO_BIND_POINT 3


/**
Maximum number of point lights
*/
#define MAX_POINT_LIGHTS 512

/**
Maximum number of lights per cluster
*/
#define MAX_LIGHTS_PER_CLUSTER 100

/**
The direct global light
*/
struct DirectLight {
    vec3 direction;
    vec3 color;
};

/**
A point light
*/
struct PointLight {
    vec4 position;
    vec4 color;
    float constant;
    float linear;
    float quadratic;
    float radius;
};

/**
A light cluster
*/
struct Cluster {
    vec4 minPoint;
    vec4 maxPoint;
    uint count;
    uint lightIndices[MAX_LIGHTS_PER_CLUSTER];
};


out vec4 FragColor;

layout(std430, binding = CLUSTER_SSBO_BIND_POINT) restrict buffer clusterGridSSBO {
    Cluster clusters[];
};

layout(std430, binding = POINT_LIGHT_SSBO_BIND_POINT) restrict buffer pointLightSSBO {
    PointLight pointLight[];
};

layout(std430, binding = DIRECT_LIGHT_SSBO_BIND_POINT) restrict buffer dirLightSSBO {
    DirectLight directLight;
};

struct Material {
    sampler2D diffuse;
    sampler2D specular;
    float shininess;
}; 

in vec3 FragPos;
in vec3 ViewFragPos;
in vec3 Normal;
in vec2 texPlane1;
in vec2 texPlane2;
in vec2 texPlane3;
in vec4 FragPosLightSpace;
in vec3 samplerIndexVec; //the indices in the atlas of textures to sample
in vec3 samplerRatioVec; //the vector of HOW MUCH to pull from each texture in the atlas


uniform vec3 viewPos;
// uniform DirLight dirLight;
// uniform PointLight pointLights[NR_POINT_LIGHTS];
// uniform SpotLight spotLight;
uniform Material material;

//texture stuff
// uniform sampler2D ourTexture;
uniform int hasTransparency;
// uniform sampler2D specularTexture;

//light depth map
uniform sampler2D shadowMap;

/**
Used for light cluster calculation
*/
uniform float zNear;
uniform float zFar;
uniform uvec3 gridSize;
uniform uvec2 screenDimensions;
uniform mat4 view;


// function prototypes
uint findCluster(vec3 FragPos, float zNear, float zFar);
vec3 CalcPointLight(PointLight pointLight, vec3 normal, vec3 fragPos, vec3 viewDir);
float calcLightIntensityTotal(vec3 normal);
float ShadowCalculation(vec4 fragPosLightSpace, vec3 lightDir, vec3 normal);
vec3 getColor(vec2 texPlane1, vec2 texPlane2, vec2 texPlane3, vec3 normal, vec3 samplerIndexVec, vec3 samplerRatioVec, Material material);

void main(){
    vec3 norm = normalize(Normal);
    vec3 viewDir = normalize(viewPos - FragPos);
    
    //grab light intensity
    vec3 lightIntensity = vec3(calcLightIntensityTotal(norm));

    //get color of base texture
    vec3 textureColor = getColor(texPlane1, texPlane2, texPlane3, norm, samplerIndexVec, samplerRatioVec, material);

    //shadow
    float shadow = ShadowCalculation(FragPosLightSpace, normalize(-directLight.direction), -norm);

    //
    //point light calculations
    uint clusterIndex = findCluster(ViewFragPos, zNear, zFar);
    uint pointLightCount = clusters[clusterIndex].count;
    for(int i = 0; i < pointLightCount; i++){
        uint pointLightIndex = clusters[clusterIndex].lightIndices[i];
        PointLight pointLight = pointLight[pointLightIndex];
        lightIntensity = lightIntensity + CalcPointLight(pointLight, norm, FragPos, viewDir);
    }
    //error checking on light clusters
    if(pointLightCount > MAX_LIGHTS_PER_CLUSTER){
        FragColor = vec4(1.0f,0.0f,0.0f,1);
        return;
    }

    //calculate final color
    vec3 finalColor = textureColor * lightIntensity * max(shadow,0.4);

    //this final calculation is for transparency
    FragColor = vec4(finalColor, 1);
}


/**
 * The function that gets the texture color based on the triplanar texture mapping and the voxel type at each point along the vert.
 * See the triplanar mapping wiki article for an explanation of math involved.
 */
vec3 getColor(vec2 texPlane1, vec2 texPlane2, vec2 texPlane3, vec3 normal, vec3 samplerIndexVec, vec3 samplerRatioVec, Material material){

    vec3 weights = abs(normal);

    //what is the index in the atlas of the texture for a given vertex
    int vert1AtlasIndex = int(samplerIndexVec.x);
    int vert2AtlasIndex = int(samplerIndexVec.y);
    int vert3AtlasIndex = int(samplerIndexVec.z);

    //what is the weight of that texture relative to the fragment
    float vert1Weight = samplerRatioVec.x;
    float vert2Weight = samplerRatioVec.y;
    float vert3Weight = samplerRatioVec.z;

    //the x-wise uv of the texture for vert1
    vec2 vert1_x_uv = vec2(
        (fract(texPlane1.x) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (mod(samplerIndexVec.x,ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL),
        (fract(texPlane1.y) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (round(samplerIndexVec.x / ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL)
    );
    //the x-wise uv of the texture for vert2
    vec2 vert2_x_uv = vec2(
        (fract(texPlane1.x) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (mod(samplerIndexVec.y,ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL),
        (fract(texPlane1.y) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (round(samplerIndexVec.y / ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL)
    );
    //the x-wise uv of the texture for vert3
    vec2 vert3_x_uv = vec2(
        (fract(texPlane1.x) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (mod(samplerIndexVec.z,ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL),
        (fract(texPlane1.y) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (round(samplerIndexVec.z / ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL)
    );
    //albedo for the X texture
    vec3 albedoX = texture(material.diffuse, vert1_x_uv).rgb * vert1Weight + texture(material.diffuse, vert2_x_uv).rgb * vert2Weight + texture(material.diffuse, vert3_x_uv).rgb * vert3Weight;


    //the y-wise uv of the texture for vert1
    vec2 vert1_y_uv = vec2(
        (fract(texPlane2.x) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (mod(samplerIndexVec.x,ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL),
        (fract(texPlane2.y) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (round(samplerIndexVec.x / ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL)
    );
    //the y-wise uv of the texture for vert2
    vec2 vert2_y_uv = vec2(
        (fract(texPlane2.x) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (mod(samplerIndexVec.y,ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL),
        (fract(texPlane2.y) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (round(samplerIndexVec.y / ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL)
    );
    //the y-wise uv of the texture for vert3
    vec2 vert3_y_uv = vec2(
        (fract(texPlane2.x) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (mod(samplerIndexVec.z,ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL),
        (fract(texPlane2.y) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (round(samplerIndexVec.z / ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL)
    );
    //albedo for the X texture
    vec3 albedoY = texture(material.diffuse, vert1_y_uv).rgb * vert1Weight + texture(material.diffuse, vert2_y_uv).rgb * vert2Weight + texture(material.diffuse, vert3_y_uv).rgb * vert3Weight;




    //the z-wise uv of the texture for vert1
    vec2 vert1_z_uv = vec2(
        (fract(texPlane3.x) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (mod(samplerIndexVec.x,ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL),
        (fract(texPlane3.y) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (round(samplerIndexVec.x / ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL)
    );
    //the z-wise uv of the texture for vert2
    vec2 vert2_z_uv = vec2(
        (fract(texPlane3.x) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (mod(samplerIndexVec.y,ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL),
        (fract(texPlane3.y) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (round(samplerIndexVec.y / ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL)
    );
    //the z-wise uv of the texture for vert3
    vec2 vert3_z_uv = vec2(
        (fract(texPlane3.x) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (mod(samplerIndexVec.z,ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL),
        (fract(texPlane3.y) * ATLAS_NORMALIZED_ELEMENT_WIDTH) + (round(samplerIndexVec.z / ATLAS_EL_PER_ROW) * ATLAS_NORMALIZED_ELEMENT_WIDTH_FULL)
    );
    //albedo for the X texture
    vec3 albedoZ = texture(material.diffuse, vert1_z_uv).rgb * vert1Weight + texture(material.diffuse, vert2_z_uv).rgb * vert2Weight + texture(material.diffuse, vert3_z_uv).rgb * vert3Weight;
    

    return (albedoX * weights.x + albedoY * weights.y + albedoZ * weights.z);
}

//
float calcLightIntensityAmbient(){
    //calculate average of ambient light
    float avg = (directLight.color.x + directLight.color.y + directLight.color.z)/3.0;
    return avg;
}

//
float calcLightIntensityDir(vec3 normal){
    vec3 lightDir = normalize(-directLight.direction);
    // diffuse shading
    float diff = max(dot(normal, lightDir), 0.0);
    
    return diff;
}

//
float calcLightIntensityTotal(vec3 normal){
    //ambient intensity
    float ambientLightIntensity = calcLightIntensityAmbient();

    //get direct intensity
    float directLightIntensity = calcLightIntensityDir(normal);

    //sum
    float total = ambientLightIntensity + directLightIntensity;
    return total;
}

//
vec3 getTotalLightColor(vec3 normal){
    //get the direct light color adjusted for intensity
    vec3 diffuseLightColor = directLight.color * calcLightIntensityDir(normal);

    //sum light colors
    vec3 totalLightColor = diffuseLightColor;
    return totalLightColor;
}

vec3 CalcPointLight(PointLight pointLight, vec3 normal, vec3 fragPos, vec3 viewDir){
    vec3 lightDir = normalize(pointLight.position.xyz - fragPos);
    // diffuse shading
    float diff = max(dot(normal, lightDir), 0.0);
    // specular shading
    // vec3 reflectDir = reflect(-lightDir, normal);
    // float spec = pow(max(dot(viewDir, reflectDir), 0.0), material.shininess);
    // attenuation
    float distance = length(pointLight.position.xyz - fragPos);
    float attenuation = 1.0 / (pointLight.constant + pointLight.linear * distance + pointLight.quadratic * (distance * distance));
    if(distance > pointLight.radius){
        attenuation = 0;
    }
    // combine results
    vec3 ambient = pointLight.color.xyz;// * vec4(texture(material.diffuse, TexCoord)).xyz;
    vec3 diffuse = pointLight.color.xyz * diff;// * vec4(texture(material.diffuse, TexCoord)).xyz;
    // vec3 specular = pLspecular[i] * spec;// * vec4(texture(material.specular, TexCoord)).xyz;
    ambient = ambient * attenuation;
    diffuse = diffuse * attenuation;
    // specular *= attenuation;
    vec3 specular = vec3(0,0,0);

    vec3 finalValue = vec3(0);
    if(distance < pointLight.radius){
        finalValue = (ambient + diffuse + specular);
        finalValue = vec3(max(finalValue.x,0),max(finalValue.y,0),max(finalValue.z,0));
    }

    return finalValue;
}

/**
Finds the light cluster this fragment belongs to
*/
uint findCluster(vec3 viewspaceFragPos, float zNear, float zFar){
    uint zTile = uint((log(abs(viewspaceFragPos.z) / zNear) * gridSize.z) / log(zFar / zNear));
    vec2 tileSize = screenDimensions / gridSize.xy;
    uvec3 tile = uvec3(gl_FragCoord.xy / tileSize, zTile);
    return tile.x + (tile.y * gridSize.x) + (tile.z * gridSize.x * gridSize.y);
}


float ShadowCalculation(vec4 fragPosLightSpace, vec3 lightDir, vec3 normal){

    // perform perspective divide
    vec3 projCoords = fragPosLightSpace.xyz / fragPosLightSpace.w;

    //transform to NDC
    projCoords = projCoords * 0.5 + 0.5;

    //get closest depth from light's POV
    float closestDepth = texture(shadowMap, projCoords.xy).r;

    //get depth of current fragment
    float currentDepth = projCoords.z;
    
    //calculate bias
    float bias = max(0.05 * (1.0 - dot(normal, lightDir)), 0.005);

    //calculate shadow value
    float shadow = currentDepth - bias > closestDepth  ? 1.0 : 0.0;

    if(projCoords.z > 1.0){
        shadow = 0.0;
    }

    //calculate dot product, if it is >0 we know they're parallel-ish therefore should disregard the shadow mapping
    //ie the fragment is already facing away from the light source
    float dotprod = dot(normalize(lightDir),normalize(normal));

    if(dotprod > 0.0){
        shadow = 0.0;
    }

    // shadow = currentDepth;

    return clamp(1.0 - shadow, 0.0, 0.7);
}